home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / B-Business / (c)b2.d64 / property eval.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  5KB  |  186 lines
  1. 10 REM ***** CASH FLOW EVALUATION *****
  2. 11 POKE53280,1:POKE53281,1:POKE53272,21
  3. 12 PRINT"[144][147]  ****  CASH FLOW EVALUATION [146] ****"
  4. 14 IF P2$="Y" THEN 20
  5. 15 IF P$="Y" OR P$="N" THEN 20
  6. 16 PRINT"DO YOU HAVE A PRINTER (Y/N)";:INPUT P$
  7. 17 IF P$="Y" OR P$="N" THEN 20
  8. 18 GOTO16
  9. 20 PRINT"CLIENT NAME =";
  10. 22 INPUT CN$
  11. 24 PRINT"PROPERTY IDENTIFICATION =";
  12. 26 INPUT PN$
  13. 28 IF P$ ="Y" THEN GOSUB 1000
  14. 30 PRINT "REAL ESTATE COST";
  15. 32 INPUT C
  16. 40 PRINT "MORTGAGE DOWN PAYMENT (% OF COST)";
  17. 50 INPUT P
  18. 60 PRINT"LOAN TERM (YEARS)";
  19. 70 INPUT Y
  20. 80 PRINT "CLOSING COSTS- POINTS (% OF COST)";
  21. 90 INPUT F
  22. 100 PRINT "MORTGAGE INTEREST RATE (%)";
  23. 110 INPUT R
  24. 120 PRINT "ADDITIONAL INITIAL COSTS";
  25. 130 INPUT I
  26. 140 PRINT "REAL ESTATE TAX PER YEAR";
  27. 150 INPUT T
  28. 160 PRINT "HEATING COSTS PER YEAR";
  29. 170 INPUT H
  30. 180 PRINT "ELECTRICITY COST PER MONTH";
  31. 190 INPUT E
  32. 200 PRINT "INSURANCE, WATER, MAINT.,ETC. PER MONTH";
  33. 210 INPUT A
  34. 220 PRINT "INCOME PER MONTH";
  35. 230 INPUT Z
  36. 232 IF P$="Y" THEN GOSUB 1020
  37. 240 L4=C-(C*(P/100))
  38. 250 T4=1+R/1200
  39. 260 M=L4*(((R/1200)*T4^(Y*12))/((T4^(Y*12))-1))
  40. 270 PRINT"[147]              CASH FLOW ANALYSIS"
  41. 280 PRINT
  42. 290 PRINT "MONTHLY MORTGAGE PAYMENTS = $";INT(100*M)/100
  43. 300 PRINT "MONTHLY TAX PAYMENTS      = $";INT(100*(T/12))/100
  44. 310 PRINT "MONTHLY EXPENSES          = $";INT(100*((H/12)+E+A))/100
  45. 320 PRINT
  46. 330 PRINT "MONTHLY INCOME            = $";INT(100*Z)/100
  47. 340 PRINT
  48. 350 X=(M+(T/12)+(H/12)+E+A)
  49. 360 PRINT "---------------------------------------"
  50. 370 PRINT "MONTHLY CASH FLOW         = $";INT(100*(Z-X))/100
  51. 380 IF Z-X<O THEN 400
  52. 390 GOTO 410
  53. 400 PRINT"----------- WARNING NEGATIVE CASH FLOW"
  54. 410 PRINT "---------------------------------------"
  55. 420 PRINT
  56. 430 PRINT
  57. 440 PRINT
  58. 444 IF P$="Y" THEN GOSUB 2200
  59. 450 REM ***** TAX DEDUCTION INFO *****
  60. 460 PRINT "WANT TAX DEDUCTION INFORMATION (Y/N)";:INPUT T$
  61. 462 IF T$="Y" THEN 480
  62. 464 IF T$="N" THEN 9000
  63. 469 GOTO 460
  64. 480 I4=L4*R/100
  65. 490 PRINT "APPROX. VALUE OF LAND";
  66. 500 INPUT V
  67. 510 PRINT "APPROX. TAX BRACKET (% OF INCOME)";
  68. 520 INPUT B4
  69. 530 PRINT "NEW (1) OR USED (2) BUILDING";
  70. 540 INPUT U
  71. 542 IF P$="Y" THEN GOSUB 3000
  72. 550 IF U=1 THEN 580
  73. 560 U1=1.25
  74. 570 GOTO 590
  75. 580 U1=2
  76. 590 D=U1*((C-V)/20)
  77. 600 G4=(H/12)+E+A+((F/100)*L4/12)
  78. 610 PRINT
  79. 620 PRINT
  80. 630 PRINT"             INVESTMENT TAX ADVANTAGE"
  81. 640 PRINT
  82. 650 PRINT "DEDUCTABLE INTEREST= $";INT(100*I4)/100;"FIRST YEAR"
  83. 660 PRINT "REAL ESTATE TAXES  = $";INT(100*T)/100;"PER YEAR"
  84. 670 PRINT "DEPRECIATION       = $";INT(100*D)/100;"FIRST YEAR"
  85. 680 PRINT "EXPENCES           = $";INT(100*G4*12)/100;"FIRST YEAR"
  86. 690 PRINT
  87. 700 PRINT "TOTAL DEDUCTABLE = $";INT(100*(I4+T+D+12*(G4)))/100;"1ST YR"
  88. 710 PRINT "TOTAL INCOME    = $";INT(100*Z*12)/100;"PER YEAR"
  89. 720 J4=(I4+D+T+(G4*12))-Z*12
  90. 730 PRINT
  91. 740 PRINT "NET DEDUCTION   = $";INT(100*J4)/100
  92. 750 T5=J4*(B4/100)
  93. 760 PRINT
  94. 770 PRINT "---------------------------------------"
  95. 780 IF T5<O THEN 810
  96. 790 PRINT "FIRST YEAR TAX BREAK =$";INT(100*T5)/100
  97. 800 GOTO 830
  98. 810 PRINT "NO TAX BREAK"
  99. 820 T5=O
  100. 830 I5=(P/100*C)+(F/100*C)+I-((Z-X)*12)
  101. 840 PRINT "---------------------------------------"
  102. 850 PRINT
  103. 860 PRINT
  104. 870 PRINT "RETURN ON INVESTMENT = "INT(((((Z-X)*12)+T5)/I5)*100);"%"
  105. 880 IF P$ ="Y" THEN GOSUB 4000
  106. 890 GOTO 9000
  107. 1000 REM *** INITIALIZE PRINTER ***
  108. 1001 IF P2$="Y" THEN 1004
  109. 1002 OPEN4,4,1
  110. 1004 PRINT#4:PRINT#4,"  ******  CASH FLOW EVALUATION  ******"
  111. 1010 PRINT#4:PRINT#4,"CLIENT NAME = ";CN$
  112. 1014 PRINT#4:PRINT#4,"PROPERTY IDENTIFICATION = ";PN$
  113. 1019 RETURN
  114. 1020 REM **** PRINT INPUT DATA ****
  115. 1030 PRINT#4:PRINT#4,"REAL ESTATE COST $";C
  116. 1040 PRINT#4:PRINT#4,"MORTGAGE DOWN PAYMENT";P;"% OF COST"
  117. 1060 PRINT#4:PRINT#4,"LOAN TERM =";Y;" YEARS"
  118. 1080 PRINT#4:PRINT#4,"CLOSING COSTS - POINTS";F;"% OF COST"
  119. 1100 PRINT#4:PRINT#4,"MORTGAGE INTEREST RATE";R;"%"
  120. 1120 PRINT#4:PRINT#4,"ADDITIONAL INITIAL COSTS = $";I
  121. 1140 PRINT#4:PRINT#4,"REAL ESTATE TAX PER YEAR = $";T
  122. 1160 PRINT#4:PRINT#4,"HEATING COSTS PER YEAR = $";H
  123. 1180 PRINT#4:PRINT#4,"ELECTRICITY COST PER YEAR = $";E
  124. 1200 PRINT#4:PRINT#4,"INSURANCE, WATER, MAINT.,ETC. = $";A;" PER MONTH"
  125. 1220 PRINT#4:PRINT#4,"INCOME PER MONTH = $";Z
  126. 1290 RETURN
  127. 2200 REM *** PRINT CASH FLOW ANALYSIS **
  128. 2210 PRINT#4:PRINT#4
  129. 2270 PRINT#4:PRINT#4,"                CASH FLOW ANALYSIS"
  130. 2280 PRINT#4
  131. 2290 PRINT#4,"MONTHLY MORTGAGE PAYMENTS = $";INT(100*M)/100
  132. 2300 PRINT#4:PRINT#4,"MONTHLY TAX PAYMENTS      = $";INT(100*(T/12))/100
  133. 2310 PRINT#4:PRINT#4,"MONTHLY EXPENSES          = $";INT(100*((H/12)+E+A))/100
  134. 2320 PRINT#4
  135. 2330 PRINT#4,"MONTHLY INCOME            = $";INT(100*Z)/100
  136. 2340 PRINT#4
  137. 2360 PRINT#4,"---------------------------------------------------"
  138. 2370 PRINT#4:PRINT#4,"MONTHLY CASH FLOW         = $";INT(100*(Z-X))/100
  139. 2380 IF Z-X<O THEN 2400
  140. 2390 GOTO 2410
  141. 2400 PRINT#4:PRINT#4,"- - - - - - WARNING NEGATIVE CASH FLOW"
  142. 2410 PRINT#4:PRINT#4,"---------------------------------------------------"
  143. 2420 PRINT#4
  144. 2430 PRINT#4
  145. 2440 PRINT#4
  146. 2500 RETURN
  147. 3000 REM ***** TAX DEDUCTION INFO ****
  148. 3100 PRINT#4:PRINT#4,"          TAX DEDUCTION INFORMATION"
  149. 3400 PRINT#4
  150. 3490 PRINT#4:PRINT#4,"APPROX. VALUE OF LAND = $";V
  151. 3510 PRINT#4:PRINT#4,"APPROX. TAX BRACKET =";B4;"% OF INCOME"
  152. 3530 PRINT#4:PRINT#4,"NEW (1) OR USED (2) BUILDING -";U
  153. 3900 RETURN
  154. 4000 REM *** PRINT TAX ADVANTAGE ***
  155. 4010 PRINT#4
  156. 4020 PRINT#4
  157. 4030 PRINT#4,"             INVESTMENT TAX ADVANTAGE"
  158. 4040 PRINT#4
  159. 4050 PRINT#4:PRINT#4,"DEDUCTABLE INTEREST = $";INT(100*I4)/100;" FIRST YEAR"
  160. 4060 PRINT#4:PRINT#4,"REAL ESTATE TAXES   = $";INT(100*T)/100;" PER YEAR"
  161. 4070 PRINT#4:PRINT#4,"DEPRECIATION        = $";INT(100*D)/100;" FIRST YEAR"
  162. 4080 PRINT#4:PRINT#4,"EXPENCES            = $";INT(100*G4*12)/100;" FIRST YEAR"
  163. 4090 PRINT#4:PRINT#4
  164. 4100 PRINT#4,"TOTAL DEDUCTABLE = $";INT(100*(I4+T+D+12*(G4)))/100;" 1ST YR"
  165. 4110 PRINT#4:PRINT#4,"TOTAL INCOME    = $";INT(100*Z*12)/100;" PER YEAR"
  166. 4130 PRINT#4
  167. 4140 PRINT#4:PRINT#4,"NET DEDUCTION   = $";INT(100*J4)/100
  168. 4160 PRINT#4
  169. 4170 PRINT#4,"---------------------------------------------------"
  170. 4180 IF T5<O THEN 4210
  171. 4190 PRINT#4:PRINT#4,"FIRST YEAR TAX BREAK = $";INT(100*T5)/100
  172. 4200 GOTO 4240
  173. 4210 PRINT#4:PRINT#4,"NO TAX BREAK"
  174. 4240 PRINT#4:PRINT#4,"---------------------------------------------------"
  175. 4250 PRINT#4
  176. 4260 PRINT#4
  177. 4270 PRINT#4,"RETURN ON INVESTMENT = "INT(((((Z-X)*12)+T5)/I5)*100);"%"
  178. 4900 RETURN
  179. 9000 REM *** END ***
  180. 9100 PRINT"DO YOU WANT TO EVALUATE ANOTHER PROPERTY (Y/N)":INPUT P2$
  181. 9110 IF P2$="Y"THEN 10
  182. 9120 IF P2$<>"N"THEN 9100
  183. 9200 PRINT"HOPE THIS WAS OF SOME HELP"
  184. 9300 CLOSE4
  185. 9990 END
  186.